meson.build 42.2 KB
Newer Older
1
# Copyright © 2017-2018 Intel Corporation
2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20

# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:

# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.

# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.

21 22 23
project(
  'mesa',
  ['c', 'cpp'],
24 25 26
  version : run_command(
    [find_program('python', 'python2', 'python3'), 'bin/meson_get_version.py']
  ).stdout(),
27
  license : 'MIT',
28
  meson_version : '>= 0.44.1',
29
  default_options : ['buildtype=debugoptimized', 'c_std=c99', 'cpp_std=c++11']
30
)
31

32 33
null_dep = dependency('', required : false)

34 35
system_has_kms_drm = ['openbsd', 'netbsd', 'freebsd', 'dragonfly', 'linux'].contains(host_machine.system())

Dylan Baker's avatar
Dylan Baker committed
36 37 38 39 40 41 42 43 44 45 46 47
# Arguments for the preprocessor, put these in a separate array from the C and
# C++ (cpp in meson terminology) arguments since they need to be added to the
# default arguments for both C and C++.
pre_args = [
  '-D__STDC_CONSTANT_MACROS',
  '-D__STDC_FORMAT_MACROS',
  '-D__STDC_LIMIT_MACROS',
  '-DVERSION="@0@"'.format(meson.project_version()),
  '-DPACKAGE_VERSION=VERSION',
  '-DPACKAGE_BUGREPORT="https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa"',
]

48
with_vulkan_icd_dir = get_option('vulkan-icd-dir')
49 50
with_tests = get_option('build-tests')
with_valgrind = get_option('valgrind')
51
with_libunwind = get_option('libunwind')
Dylan Baker's avatar
Dylan Baker committed
52
with_asm = get_option('asm')
Dylan Baker's avatar
Dylan Baker committed
53
with_osmesa = get_option('osmesa')
Dylan Baker's avatar
Dylan Baker committed
54 55
with_swr_arches = get_option('swr-arches')
with_tools = get_option('tools')
56 57 58
if with_tools.contains('all')
  with_tools = ['freedreno', 'glsl', 'intel', 'nir', 'nouveau']
endif
59 60
if get_option('texture-float')
  pre_args += '-DTEXTURE_FLOAT_ENABLED'
Dylan Baker's avatar
Dylan Baker committed
61
  warning('Floating-point texture enabled. Please consult docs/patents.txt and your lawyer before building mesa.')
62
endif
Dylan Baker's avatar
Dylan Baker committed
63

64 65 66 67
dri_drivers_path = get_option('dri-drivers-path')
if dri_drivers_path == ''
  dri_drivers_path = join_paths(get_option('libdir'), 'dri')
endif
68 69 70 71
dri_search_path = get_option('dri-search-path')
if dri_search_path == ''
  dri_search_path = join_paths(get_option('prefix'), dri_drivers_path)
endif
72

Dylan Baker's avatar
Dylan Baker committed
73 74 75 76
with_gles1 = get_option('gles1')
with_gles2 = get_option('gles2')
with_opengl = get_option('opengl')
with_any_opengl = with_opengl or with_gles1 or with_gles2
Dylan Baker's avatar
Dylan Baker committed
77 78
# Only build shared_glapi if at least one OpenGL API is enabled
with_shared_glapi = get_option('shared-glapi') and with_any_opengl
Dylan Baker's avatar
Dylan Baker committed
79 80 81 82 83 84 85 86 87 88 89 90 91 92 93


# shared-glapi is required if at least two OpenGL APIs are being built
if not with_shared_glapi
  if ((with_gles1 and with_gles2) or (with_gles1 and with_opengl)
      or (with_gles2 and with_opengl))
    error('shared-glapi required for building two or more of OpenGL, OpenGL ES 1.x, OpenGL ES 2.x')
  endif
endif

# We require OpenGL for OpenGL ES
if (with_gles1 or with_gles2) and not with_opengl
  error('building OpenGL ES without OpenGL is not supported.')
endif

94 95
system_has_kms_drm = ['openbsd', 'netbsd', 'freebsd', 'dragonfly', 'linux'].contains(host_machine.system())

Dylan Baker's avatar
Dylan Baker committed
96
with_dri = false
Ville Syrjälä's avatar
Ville Syrjälä committed
97
with_dri_i915 = false
Dylan Baker's avatar
Dylan Baker committed
98
with_dri_i965 = false
Dylan Baker's avatar
Dylan Baker committed
99
with_dri_r100 = false
Dylan Baker's avatar
Dylan Baker committed
100
with_dri_r200 = false
101
with_dri_nouveau = false
Dylan Baker's avatar
Dylan Baker committed
102
with_dri_swrast = false
Dylan Baker's avatar
Dylan Baker committed
103
_drivers = get_option('dri-drivers')
Dylan Baker's avatar
Dylan Baker committed
104
if _drivers.contains('auto')
105
  if system_has_kms_drm
106
    # TODO: PPC, Sparc
107
    if ['x86', 'x86_64'].contains(host_machine.cpu_family())
Dylan Baker's avatar
Dylan Baker committed
108
      _drivers = ['i915', 'i965', 'r100', 'r200', 'nouveau']
109
    elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
Dylan Baker's avatar
Dylan Baker committed
110
      _drivers = ['']
111 112 113
    else
      error('Unknown architecture. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.')
    endif
114
  elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
115
    # only swrast would make sense here, but gallium swrast is a much better default
Dylan Baker's avatar
Dylan Baker committed
116
    _drivers = ['']
117 118 119 120
  else
    error('Unknown OS. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.')
  endif
endif
Dylan Baker's avatar
Dylan Baker committed
121 122 123 124 125 126 127
if _drivers != ['']
  with_dri_i915 = _drivers.contains('i915')
  with_dri_i965 = _drivers.contains('i965')
  with_dri_r100 = _drivers.contains('r100')
  with_dri_r200 = _drivers.contains('r200')
  with_dri_nouveau = _drivers.contains('nouveau')
  with_dri_swrast = _drivers.contains('swrast')
Dylan Baker's avatar
Dylan Baker committed
128 129 130
  with_dri = true
endif

Dylan Baker's avatar
Dylan Baker committed
131
with_gallium = false
132
with_gallium_pl111 = false
Dylan Baker's avatar
Dylan Baker committed
133
with_gallium_radeonsi = false
Dylan Baker's avatar
Dylan Baker committed
134
with_gallium_r300 = false
Dylan Baker's avatar
Dylan Baker committed
135
with_gallium_r600 = false
136
with_gallium_nouveau = false
Rob Clark's avatar
Rob Clark committed
137
with_gallium_freedreno = false
138
with_gallium_softpipe = false
139
with_gallium_vc4 = false
140
with_gallium_v3d = false
141
with_gallium_etnaviv = false
Dylan Baker's avatar
Dylan Baker committed
142
with_gallium_imx = false
Thierry Reding's avatar
Thierry Reding committed
143
with_gallium_tegra = false
Dylan Baker's avatar
Dylan Baker committed
144
with_gallium_i915 = false
145
with_gallium_svga = false
Dylan Baker's avatar
Dylan Baker committed
146
with_gallium_virgl = false
Dylan Baker's avatar
Dylan Baker committed
147
with_gallium_swr = false
Dylan Baker's avatar
Dylan Baker committed
148
_drivers = get_option('gallium-drivers')
Dylan Baker's avatar
Dylan Baker committed
149
if _drivers.contains('auto')
150
  if system_has_kms_drm
151 152
    # TODO: PPC, Sparc
    if ['x86', 'x86_64'].contains(host_machine.cpu_family())
Dylan Baker's avatar
Dylan Baker committed
153 154 155
      _drivers = [
        'r300', 'r600', 'radeonsi', 'nouveau', 'virgl', 'svga', 'swrast'
      ]
156
    elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
Dylan Baker's avatar
Dylan Baker committed
157
      _drivers = [
158
        'pl111', 'v3d', 'vc4', 'freedreno', 'etnaviv', 'imx', 'nouveau',
Dylan Baker's avatar
Dylan Baker committed
159 160
        'tegra', 'virgl', 'swrast',
      ]
161 162 163
    else
      error('Unknown architecture. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.')
    endif
164
  elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
Dylan Baker's avatar
Dylan Baker committed
165
    _drivers = ['swrast']
166 167 168 169
  else
    error('Unknown OS. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.')
  endif
endif
Dylan Baker's avatar
Dylan Baker committed
170 171 172 173 174 175 176 177
if _drivers != ['']
  with_gallium_pl111 = _drivers.contains('pl111')
  with_gallium_radeonsi = _drivers.contains('radeonsi')
  with_gallium_r300 = _drivers.contains('r300')
  with_gallium_r600 = _drivers.contains('r600')
  with_gallium_nouveau = _drivers.contains('nouveau')
  with_gallium_freedreno = _drivers.contains('freedreno')
  with_gallium_softpipe = _drivers.contains('swrast')
178
  with_gallium_v3d = _drivers.contains('v3d')
Dylan Baker's avatar
Dylan Baker committed
179 180 181 182 183 184 185 186
  with_gallium_vc4 = _drivers.contains('vc4')
  with_gallium_etnaviv = _drivers.contains('etnaviv')
  with_gallium_imx = _drivers.contains('imx')
  with_gallium_tegra = _drivers.contains('tegra')
  with_gallium_i915 = _drivers.contains('i915')
  with_gallium_svga = _drivers.contains('svga')
  with_gallium_virgl = _drivers.contains('virgl')
  with_gallium_swr = _drivers.contains('swr')
Dylan Baker's avatar
Dylan Baker committed
187
  with_gallium = true
188 189 190 191 192 193 194
  if system_has_kms_drm
    _glx = get_option('glx')
    _egl = get_option('egl')
    if _glx == 'dri' or _egl == 'true' or (_glx == 'disabled' and _egl != 'false')
      with_dri = true
    endif
  endif
Ville Syrjälä's avatar
Ville Syrjälä committed
195 196
endif

197 198 199 200
with_intel_vk = false
with_amd_vk = false
with_any_vk = false
_vulkan_drivers = get_option('vulkan-drivers')
Dylan Baker's avatar
Dylan Baker committed
201
if _vulkan_drivers.contains('auto')
202
  if system_has_kms_drm
203
    if host_machine.cpu_family().startswith('x86')
Dylan Baker's avatar
Dylan Baker committed
204
      _vulkan_drivers = ['amd', 'intel']
205 206 207
    else
      error('Unknown architecture. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.')
    endif
208
  elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
209
    # No vulkan driver supports windows or macOS currently
Dylan Baker's avatar
Dylan Baker committed
210
    _vulkan_drivers = ['']
211 212
  else
    error('Unknown OS. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.')
213 214
  endif
endif
Dylan Baker's avatar
Dylan Baker committed
215
if _vulkan_drivers != ['']
216 217
  with_intel_vk = _vulkan_drivers.contains('intel')
  with_amd_vk = _vulkan_drivers.contains('amd')
Dylan Baker's avatar
Dylan Baker committed
218
  with_any_vk = true
219 220
endif

Dylan Baker's avatar
Dylan Baker committed
221
if with_dri_swrast and (with_gallium_softpipe or with_gallium_swr)
Dylan Baker's avatar
Dylan Baker committed
222 223
  error('Only one swrast provider can be built')
endif
Dylan Baker's avatar
Dylan Baker committed
224 225 226
if with_dri_i915 and with_gallium_i915
  error('Only one i915 provider can be built')
endif
Dylan Baker's avatar
Dylan Baker committed
227 228 229
if with_gallium_imx and not with_gallium_etnaviv
  error('IMX driver requires etnaviv driver')
endif
230 231 232
if with_gallium_pl111 and not with_gallium_vc4
  error('pl111 driver requires vc4 driver')
endif
Thierry Reding's avatar
Thierry Reding committed
233 234 235
if with_gallium_tegra and not with_gallium_nouveau
  error('tegra driver requires nouveau driver')
endif
Dylan Baker's avatar
Dylan Baker committed
236

237 238 239 240
if host_machine.system() == 'darwin'
  with_dri_platform = 'apple'
elif ['windows', 'cygwin'].contains(host_machine.system())
  with_dri_platform = 'windows'
Greg V's avatar
Greg V committed
241
elif system_has_kms_drm
242 243 244 245 246 247
  with_dri_platform = 'drm'
else
  # FIXME: haiku doesn't use dri, and xlib doesn't use dri, probably should
  # assert here that one of those cases has been met.
  # FIXME: GNU (hurd) ends up here as well, but meson doesn't officially
  # support Hurd at time of writing (2017/11)
Greg V's avatar
Greg V committed
248
  # FIXME: illumos ends up here as well
249 250
  with_dri_platform = 'none'
endif
Dylan Baker's avatar
Dylan Baker committed
251

Eric Engestrom's avatar
Eric Engestrom committed
252
with_platform_android = false
253 254
with_platform_wayland = false
with_platform_x11 = false
Dylan Baker's avatar
Dylan Baker committed
255
with_platform_drm = false
Dylan Baker's avatar
Dylan Baker committed
256 257
with_platform_surfaceless = false
egl_native_platform = ''
258
_platforms = get_option('platforms')
Dylan Baker's avatar
Dylan Baker committed
259
if _platforms.contains('auto')
Greg V's avatar
Greg V committed
260
  if system_has_kms_drm
Dylan Baker's avatar
Dylan Baker committed
261
    _platforms = ['x11', 'wayland', 'drm', 'surfaceless']
262
  elif ['darwin', 'windows', 'cygwin'].contains(host_machine.system())
Dylan Baker's avatar
Dylan Baker committed
263
    _platforms = ['x11', 'surfaceless']
264
  elif ['haiku'].contains(host_machine.system())
Dylan Baker's avatar
Dylan Baker committed
265
    _platforms = ['haiku']
Dylan Baker's avatar
Dylan Baker committed
266
  else
267
    error('Unknown OS. Please pass -Dplatforms to set platforms. Patches gladly accepted to fix this.')
Dylan Baker's avatar
Dylan Baker committed
268 269
  endif
endif
Dylan Baker's avatar
Dylan Baker committed
270 271 272 273 274 275 276 277
if _platforms != ['']
  with_platform_android = _platforms.contains('android')
  with_platform_x11 = _platforms.contains('x11')
  with_platform_wayland = _platforms.contains('wayland')
  with_platform_drm = _platforms.contains('drm')
  with_platform_haiku = _platforms.contains('haiku')
  with_platform_surfaceless = _platforms.contains('surfaceless')
  egl_native_platform = _platforms[0]
278 279
endif

Dylan Baker's avatar
Dylan Baker committed
280 281 282 283
with_glx = get_option('glx')
if with_glx == 'auto'
  if with_dri
    with_glx = 'dri'
284 285
  elif with_platform_haiku
    with_glx = 'disabled'
Dylan Baker's avatar
Dylan Baker committed
286
  elif with_gallium
287 288
    # Even when building just gallium drivers the user probably wants dri
    with_glx = 'dri'
289
    with_dri = true
Dylan Baker's avatar
Dylan Baker committed
290 291 292 293 294 295 296 297 298
  elif with_platform_x11 and with_any_opengl and not with_any_vk
    # The automatic behavior should not be to turn on xlib based glx when
    # building only vulkan drivers
    with_glx = 'xlib'
  else
    with_glx = 'disabled'
  endif
endif

299
if not (with_dri or with_gallium or with_glx == 'xlib' or with_glx == 'gallium-xlib')
Dylan Baker's avatar
Dylan Baker committed
300 301 302 303 304 305 306
  with_gles1 = false
  with_gles2 = false
  with_opengl = false
  with_any_opengl = false
  with_shared_glapi = false
endif

307 308 309
_gbm = get_option('gbm')
if _gbm == 'auto'
  with_gbm = system_has_kms_drm and with_dri
Dylan Baker's avatar
Dylan Baker committed
310
else
311 312 313 314
  with_gbm = _gbm == 'true'
endif
if with_gbm and not system_has_kms_drm
  error('GBM only supports DRM/KMS platforms')
Dylan Baker's avatar
Dylan Baker committed
315 316
endif

Dylan Baker's avatar
Dylan Baker committed
317 318 319
_egl = get_option('egl')
if _egl == 'auto'
  with_egl = with_dri and with_shared_glapi and egl_native_platform != ''
320
elif _egl == 'true'
Dylan Baker's avatar
Dylan Baker committed
321 322 323 324 325 326
  if not with_dri
    error('EGL requires dri')
  elif not with_shared_glapi
    error('EGL requires shared-glapi')
  elif egl_native_platform == ''
    error('No platforms specified, consider -Dplatforms=drm,x11 at least')
327 328
  elif not ['disabled', 'dri'].contains(with_glx)
    error('EGL requires dri, but a GLX is being built without dri')
Dylan Baker's avatar
Dylan Baker committed
329 330 331 332 333 334
  endif
  with_egl = true
else
  with_egl = false
endif

Dylan Baker's avatar
Dylan Baker committed
335 336 337 338 339 340 341
if with_egl and not (with_platform_drm or with_platform_surfaceless)
  if with_gallium_radeonsi
    error('RadeonSI requires drm or surfaceless platform when using EGL')
  endif
  if with_gallium_virgl
    error('Virgl requires drm or surfaceless platform when using EGL')
  endif
Dylan Baker's avatar
Dylan Baker committed
342 343
endif

Dylan Baker's avatar
Dylan Baker committed
344
pre_args += '-DGLX_USE_TLS'
Dylan Baker's avatar
Dylan Baker committed
345
if with_glx != 'disabled'
346 347 348 349 350 351
  if not (with_platform_x11 and with_any_opengl)
    if with_glx == 'auto'
      with_glx = 'disabled'
    else
      error('Cannot build GLX support without X11 platform support and at least one OpenGL API')
    endif
Dylan Baker's avatar
Dylan Baker committed
352 353 354
  elif with_glx == 'gallium-xlib' 
    if not with_gallium
      error('Gallium-xlib based GLX requires at least one gallium driver')
355 356
    elif not with_gallium_softpipe
      error('Gallium-xlib based GLX requires softpipe or llvmpipe.')
Dylan Baker's avatar
Dylan Baker committed
357 358 359
    elif with_dri
      error('gallium-xlib conflicts with any dri driver')
    endif
Dylan Baker's avatar
Dylan Baker committed
360
  elif with_glx == 'xlib' 
Dylan Baker's avatar
Dylan Baker committed
361
    if with_dri
Dylan Baker's avatar
Dylan Baker committed
362
      error('xlib conflicts with any dri driver')
Dylan Baker's avatar
Dylan Baker committed
363
    endif
Dylan Baker's avatar
Dylan Baker committed
364 365
  elif with_glx == 'dri' and not with_dri
    error('dri based GLX requires at least one DRI driver')
Dylan Baker's avatar
Dylan Baker committed
366 367 368 369
  endif
endif

with_glvnd = get_option('glvnd')
370 371 372 373 374 375
if with_glvnd
  if with_glx == 'xlib' or with_glx == 'gallium-xlib'
    error('Cannot build glvnd support for GLX that is not DRI based.')
  elif with_glx == 'disabled' and not with_egl
    error('glvnd requires DRI based GLX and/or EGL')
  endif
Dylan Baker's avatar
Dylan Baker committed
376 377 378 379 380
endif

# TODO: toggle for this
with_glx_direct = true

381 382 383 384
if with_vulkan_icd_dir == ''
  with_vulkan_icd_dir = join_paths(get_option('datadir'), 'vulkan/icd.d')
endif

385
with_dri2 = (with_dri or with_any_vk) and with_dri_platform == 'drm'
386 387
_dri3 = get_option('dri3')
if _dri3 == 'auto'
Eric Engestrom's avatar
Eric Engestrom committed
388
  with_dri3 = system_has_kms_drm and with_dri2
389
else
390
  with_dri3 = _dri3 == 'true'
391 392 393 394 395
endif

if with_any_vk and (with_platform_x11 and not with_dri3)
  error('Vulkan drivers require dri3 for X11 support')
endif
Dylan Baker's avatar
Dylan Baker committed
396
if with_dri or with_gallium
397
  if with_glx == 'disabled' and not with_egl and not with_platform_haiku
Dylan Baker's avatar
Dylan Baker committed
398 399
    error('building dri or gallium drivers require at least one window system')
  endif
400 401
endif

402 403
prog_pkgconfig = find_program('pkg-config')

404
_vdpau = get_option('gallium-vdpau')
405 406 407
if not system_has_kms_drm
  if _vdpau == 'true'
    error('VDPAU state tracker can only be build on unix-like OSes.')
408
  else
409
    _vdpau = 'false'
410
  endif
411 412
elif not with_platform_x11
  if _vdpau == 'true'
413
    error('VDPAU state tracker requires X11 support.')
414 415 416 417 418 419
  else
    _vdpau = 'false'
  endif
elif not (with_gallium_r300 or with_gallium_r600 or with_gallium_radeonsi or
          with_gallium_nouveau)
  if _vdpau == 'true'
420
    error('VDPAU state tracker requires at least one of the following gallium drivers: r300, r600, radeonsi, nouveau.')
421 422
  else
    _vdpau = 'false'
423
  endif
424 425
elif _vdpau == 'auto'
  _vdpau = 'true'
426
endif
427
with_gallium_vdpau = _vdpau == 'true'
428
dep_vdpau = null_dep
429
if with_gallium_vdpau
430
  dep_vdpau = dependency('vdpau', version : '>= 1.1')
431
  dep_vdpau = declare_dependency(
432
    compile_args : run_command(prog_pkgconfig, ['vdpau', '--cflags']).stdout().split()
433 434 435 436 437 438 439 440 441 442 443
  )
endif

if with_gallium_vdpau
  pre_args += '-DHAVE_ST_VDPAU'
endif
vdpau_drivers_path = get_option('vdpau-libs-path')
if vdpau_drivers_path == ''
  vdpau_drivers_path = join_paths(get_option('libdir'), 'vdpau')
endif

444
_xvmc = get_option('gallium-xvmc')
445 446 447
if not system_has_kms_drm
  if _xvmc == 'true'
    error('XVMC state tracker can only be build on unix-like OSes.')
448
  else
449
    _xvmc = 'false'
450
  endif
451 452
elif not with_platform_x11
  if _xvmc == 'true'
453
    error('XVMC state tracker requires X11 support.')
454 455 456 457 458
  else
    _xvmc = 'false'
  endif
elif not (with_gallium_r600 or with_gallium_nouveau)
  if _xvmc == 'true'
459
    error('XVMC state tracker requires at least one of the following gallium drivers: r600, nouveau.')
460 461
  else
    _xvmc = 'false'
462
  endif
463 464
elif _xvmc == 'auto'
  _xvmc = 'true'
465
endif
466
with_gallium_xvmc = _xvmc == 'true'
467
dep_xvmc = null_dep
468
if with_gallium_xvmc
469
  dep_xvmc = dependency('xvmc', version : '>= 1.0.6')
470 471 472 473 474 475 476
endif

xvmc_drivers_path = get_option('xvmc-libs-path')
if xvmc_drivers_path == ''
  xvmc_drivers_path = get_option('libdir')
endif

477
_omx = get_option('gallium-omx')
478
if not system_has_kms_drm
479
  if ['auto', 'disabled'].contains(_omx)
480
    _omx = 'disabled'
481 482
  else
    error('OMX state tracker can only be built on unix-like OSes.')
483
  endif
484
elif not (with_platform_x11 or with_platform_drm)
485
  if ['auto', 'disabled'].contains(_omx)
486
    _omx = 'disabled'
487 488
  else
    error('OMX state tracker requires X11 or drm platform support.')
489 490
  endif
elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
491
  if ['auto', 'disabled'].contains(_omx)
492
    _omx = 'disabled'
493 494
  else
    error('OMX state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
495
  endif
496
endif
497 498
with_gallium_omx = _omx
dep_omx = null_dep
499
dep_omx_other = []
Mathias Fröhlich's avatar
Mathias Fröhlich committed
500
if ['auto', 'bellagio'].contains(_omx)
501
  dep_omx = dependency(
Mathias Fröhlich's avatar
Mathias Fröhlich committed
502
    'libomxil-bellagio', required : _omx == 'bellagio'
503 504 505 506 507
  )
  if dep_omx.found()
    with_gallium_omx = 'bellagio'
  endif
endif
Mathias Fröhlich's avatar
Mathias Fröhlich committed
508 509
if ['auto', 'tizonia'].contains(_omx)
  if with_dri and with_egl
510 511
    dep_omx = dependency(
      'libtizonia', version : '>= 0.10.0',
Mathias Fröhlich's avatar
Mathias Fröhlich committed
512
      required : _omx == 'tizonia',
513 514
    )
    dep_omx_other = [
Mathias Fröhlich's avatar
Mathias Fröhlich committed
515 516
      dependency('libtizplatform', required : _omx == 'tizonia'),
      dependency('tizilheaders', required : _omx == 'tizonia'),
517 518 519 520
    ]
    if dep_omx.found() and dep_omx_other[0].found() and dep_omx_other[1].found()
      with_gallium_omx = 'tizonia'
    endif
Mathias Fröhlich's avatar
Mathias Fröhlich committed
521 522
  elif _omx == 'tizonia'
    error('OMX-Tizonia state tracker requires dri and egl')
523
  endif
524
endif
Mathias Fröhlich's avatar
Mathias Fröhlich committed
525 526 527 528 529
if _omx == 'auto'
  with_gallium_omx = 'disabled'
else
  with_gallium_omx = _omx
endif
530

531 532 533 534 535 536
pre_args += [
  '-DENABLE_ST_OMX_BELLAGIO=' + (with_gallium_omx == 'bellagio' ? '1' : '0'),
  '-DENABLE_ST_OMX_TIZONIA=' + (with_gallium_omx == 'tizonia' ? '1' : '0'),
]


537
omx_drivers_path = get_option('omx-libs-path')
538

539
if with_gallium_omx != 'disabled'
540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562
  # Figure out where to put the omx driver.
  # FIXME: this could all be vastly simplified by adding a 'defined_variable'
  # argument to meson's get_pkgconfig_variable method.
  if omx_drivers_path == ''
    _omx_libdir = dep_omx.get_pkgconfig_variable('libdir')
    _omx_drivers_dir = dep_omx.get_pkgconfig_variable('pluginsdir')
    if _omx_libdir == get_option('libdir')
      omx_drivers_path = _omx_drivers_dir
    else
      _omx_base_dir = []
      # This will fail on windows. Does OMX run on windows?
      _omx_libdir = _omx_libdir.split('/')
      _omx_drivers_dir = _omx_drivers_dir.split('/')
      foreach o : _omx_drivers_dir
        if not _omx_libdir.contains(o)
          _omx_base_dir += o
        endif
      endforeach
      omx_drivers_path = join_paths(get_option('libdir'), _omx_base_dir)
    endif
  endif
endif

563
_va = get_option('gallium-va')
Eric Engestrom's avatar
Eric Engestrom committed
564 565 566
if not system_has_kms_drm
  if _va == 'true'
    error('VA state tracker can only be built on unix-like OSes.')
567
  else
Eric Engestrom's avatar
Eric Engestrom committed
568
    _va = 'false'
569
  endif
Eric Engestrom's avatar
Eric Engestrom committed
570 571
elif not (with_platform_x11 or with_platform_drm)
  if _va == 'true'
572
    error('VA state tracker requires X11 or drm or wayland platform support.')
Eric Engestrom's avatar
Eric Engestrom committed
573 574 575 576 577
  else
    _va = 'false'
  endif
elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
  if _va == 'true'
578
    error('VA state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
Eric Engestrom's avatar
Eric Engestrom committed
579 580
  else
    _va = 'false'
581
  endif
Eric Engestrom's avatar
Eric Engestrom committed
582 583
elif _va == 'auto'
  _va = 'true'
584
endif
Eric Engestrom's avatar
Eric Engestrom committed
585
with_gallium_va = _va == 'true'
586
dep_va = null_dep
587
if with_gallium_va
588
  dep_va = dependency('libva', version : '>= 0.39.0')
589
  dep_va_headers = declare_dependency(
590
    compile_args : run_command(prog_pkgconfig, ['libva', '--cflags']).stdout().split()
591 592 593 594 595 596 597 598
  )
endif

va_drivers_path = get_option('va-libs-path')
if va_drivers_path == ''
  va_drivers_path = join_paths(get_option('libdir'), 'dri')
endif

599
_xa = get_option('gallium-xa')
Eric Engestrom's avatar
Eric Engestrom committed
600 601 602
if not system_has_kms_drm
  if _xa == 'true'
    error('XA state tracker can only be built on unix-like OSes.')
603
  else
Eric Engestrom's avatar
Eric Engestrom committed
604
    _xa = 'false'
605
  endif
Eric Engestrom's avatar
Eric Engestrom committed
606 607 608
elif not (with_gallium_nouveau or with_gallium_freedreno or with_gallium_i915
          or with_gallium_svga)
  if _xa == 'true'
609
    error('XA state tracker requires at least one of the following gallium drivers: nouveau, freedreno, i915, svga.')
Eric Engestrom's avatar
Eric Engestrom committed
610 611
  else
    _xa = 'false'
612 613
  endif
endif
Eric Engestrom's avatar
Eric Engestrom committed
614
with_gallium_xa = _xa != 'false'
615

616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633
d3d_drivers_path = get_option('d3d-drivers-path')
if d3d_drivers_path == ''
  d3d_drivers_path = join_paths(get_option('libdir'), 'd3d')
endif

with_gallium_st_nine =  get_option('gallium-nine')
if with_gallium_st_nine
  if not with_gallium_softpipe
    error('The nine state tracker requires gallium softpipe/llvmpipe.')
  elif not (with_gallium_radeonsi or with_gallium_nouveau or with_gallium_r600
            or with_gallium_r300 or with_gallium_svga or with_gallium_i915)
    error('The nine state tracker requires at least on non-swrast gallium driver.')
  endif
  if not with_dri3
    error('Using nine with wine requires dri3')
  endif
endif

Dylan Baker's avatar
Dylan Baker committed
634
_opencl = get_option('gallium-opencl')
Dylan Baker's avatar
Dylan Baker committed
635
if _opencl != 'disabled'
Dylan Baker's avatar
Dylan Baker committed
636 637 638 639 640 641 642 643 644
  if not with_gallium
    error('OpenCL Clover implementation requires at least one gallium driver.')
  endif

  # TODO: alitvec?
  dep_clc = dependency('libclc')
  with_gallium_opencl = true
  with_opencl_icd = _opencl == 'icd'
else
645
  dep_clc = null_dep
Dylan Baker's avatar
Dylan Baker committed
646 647 648 649
  with_gallium_opencl = false
  with_gallium_icd = false
endif

Dylan Baker's avatar
Dylan Baker committed
650
gl_pkgconfig_c_flags = []
651
if with_platform_x11
652
  if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
653 654
    pre_args += '-DHAVE_X11_PLATFORM'
  endif
655
  if with_glx == 'xlib' or with_glx == 'gallium-xlib'
Dylan Baker's avatar
Dylan Baker committed
656
    pre_args += '-DUSE_XSHM'
657 658 659 660 661 662 663
  else
    pre_args += '-DGLX_INDIRECT_RENDERING'
    if with_glx_direct
      pre_args += '-DGLX_DIRECT_RENDERING'
    endif
    if with_dri_platform == 'drm'
      pre_args += '-DGLX_USE_DRM'
Dylan Baker's avatar
Dylan Baker committed
664 665
    elif with_dri_platform == 'apple'
      pre_args += '-DGLX_USE_APPLEGL'
Jon Turney's avatar
Jon Turney committed
666 667
    elif with_dri_platform == 'windows'
      pre_args += '-DGLX_USE_WINDOWSGL'
668 669
    endif
  endif
Dylan Baker's avatar
Dylan Baker committed
670 671 672 673 674 675 676 677 678 679 680 681
else
  pre_args += '-DMESA_EGL_NO_X11_HEADERS'
  gl_pkgconfig_c_flags += '-DMESA_EGL_NO_X11_HEADERS'
endif
if with_platform_drm
  if with_egl and not with_gbm
    error('EGL drm platform requires gbm')
  endif
  pre_args += '-DHAVE_DRM_PLATFORM'
endif
if with_platform_surfaceless
  pre_args += '-DHAVE_SURFACELESS_PLATFORM'
682
endif
Eric Engestrom's avatar
Eric Engestrom committed
683 684 685 686 687 688 689 690
if with_platform_android
  dep_android = [
    dependency('cutils'),
    dependency('hardware'),
    dependency('sync'),
  ]
  pre_args += '-DHAVE_ANDROID_PLATFORM'
endif
691 692 693
if with_platform_haiku
  pre_args += '-DHAVE_HAIKU_PLATFORM'
endif
694

695
prog_python2 = find_program('python2')
Dylan Baker's avatar
Dylan Baker committed
696 697 698 699
has_mako = run_command(prog_python2, '-c', 'import mako')
if has_mako.returncode() != 0
  error('Python (2.x) mako module required to build mesa.')
endif
700 701 702

cc = meson.get_compiler('c')
if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.4.6')
703
  error('When using GCC, version 4.4.6 or later is required.')
704 705
endif

706 707
# Define DEBUG for debug builds only (debugoptimized is not included on this one)
if get_option('buildtype') == 'debug'
708 709 710
  pre_args += '-DDEBUG'
endif

711 712 713 714 715 716
if get_option('shader-cache')
  pre_args += '-DENABLE_SHADER_CACHE'
elif with_amd_vk
  error('Radv requires shader cache support')
endif

717 718 719 720 721 722 723 724
# Check for GCC style builtins
foreach b : ['bswap32', 'bswap64', 'clz', 'clzll', 'ctz', 'expect', 'ffs',
             'ffsll', 'popcount', 'popcountll', 'unreachable']
  if cc.has_function(b)
    pre_args += '-DHAVE___BUILTIN_@0@'.format(b.to_upper())
  endif
endforeach

725
# check for GCC __attribute__
726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742
foreach a : ['const', 'flatten', 'malloc', 'pure', 'unused',
             'warn_unused_result', 'weak',]
  if cc.compiles('int foo(void) __attribute__((@0@));'.format(a),
                 name : '__attribute__((@0@))'.format(a))
    pre_args += '-DHAVE_FUNC_ATTRIBUTE_@0@'.format(a.to_upper())
  endif
endforeach
if cc.compiles('int foo(const char *p, ...) __attribute__((format(printf, 1, 2)));',
               name : '__attribute__((format(...)))')
  pre_args += '-DHAVE_FUNC_ATTRIBUTE_FORMAT'
endif
if cc.compiles('struct __attribute__((packed)) foo { int bar; };',
               name : '__attribute__((packed))')
  pre_args += '-DHAVE_FUNC_ATTRIBUTE_PACKED'
endif
if cc.compiles('int *foo(void) __attribute__((returns_nonnull));',
               name : '__attribute__((returns_nonnull))')
743
  pre_args += '-DHAVE_FUNC_ATTRIBUTE_RETURNS_NONNULL'
744 745 746 747 748 749
endif
if cc.compiles('''int foo_def(void) __attribute__((visibility("default")));
                  int foo_hid(void) __attribute__((visibility("hidden")));
                  int foo_int(void) __attribute__((visibility("internal")));
                  int foo_pro(void) __attribute__((visibility("protected")));''',
               name : '__attribute__((visibility(...)))')
750
  pre_args += '-DHAVE_FUNC_ATTRIBUTE_VISIBILITY'
751 752 753 754 755
endif
if cc.compiles('int foo(void) { return 0; } int bar(void) __attribute__((alias("foo")));',
               name : '__attribute__((alias(...)))')
  pre_args += '-DHAVE_FUNC_ATTRIBUTE_ALIAS'
endif
Jason Ekstrand's avatar
Jason Ekstrand committed
756 757 758 759
if cc.compiles('int foo(void) __attribute__((__noreturn__));',
               name : '__attribute__((__noreturn__))')
  pre_args += '-DHAVE_FUNC_ATTRIBUTE_NORETURN'
endif
760 761

# TODO: this is very incomplete
Jon Turney's avatar
Jon Turney committed
762
if ['linux', 'cygwin'].contains(host_machine.system())
763 764 765
  pre_args += '-D_GNU_SOURCE'
endif

766
# Check for generic C arguments
767 768 769 770 771 772 773 774 775 776 777 778 779
c_args = []
foreach a : ['-Wall', '-Werror=implicit-function-declaration',
             '-Werror=missing-prototypes', '-fno-math-errno',
             '-fno-trapping-math', '-Qunused-arguments']
  if cc.has_argument(a)
    c_args += a
  endif
endforeach
c_vis_args = []
if cc.has_argument('-fvisibility=hidden')
  c_vis_args += '-fvisibility=hidden'
endif

780 781 782 783 784 785 786 787 788 789
# Check for generic C++ arguments
cpp = meson.get_compiler('cpp')
cpp_args = []
foreach a : ['-Wall', '-fno-math-errno', '-fno-trapping-math',
             '-Qunused-arguments']
  if cpp.has_argument(a)
    cpp_args += a
  endif
endforeach

790 791 792 793 794 795 796 797 798 799 800 801 802
# For some reason, the test for -Wno-foo always succeeds with gcc, even if the
# option is not supported. Hence, check for -Wfoo instead.
if cpp.has_argument('-Wnon-virtual-dtor')
  cpp_args += '-Wno-non-virtual-dtor'
endif

no_override_init_args = []
foreach a : ['override-init', 'initializer-overrides']
  if cc.has_argument('-W' + a)
    no_override_init_args += '-Wno-' + a
  endif
endforeach

803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821
cpp_vis_args = []
if cpp.has_argument('-fvisibility=hidden')
  cpp_vis_args += '-fvisibility=hidden'
endif

# Check for C and C++ arguments for MSVC2013 compatibility. These are only used
# in parts of the mesa code base that need to compile with old versions of
# MSVC, mainly common code
c_msvc_compat_args = []
cpp_msvc_compat_args = []
foreach a : ['-Werror=pointer-arith', '-Werror=vla']
  if cc.has_argument(a)
    c_msvc_compat_args += a
  endif
  if cpp.has_argument(a)
    cpp_msvc_compat_args += a
  endif
endforeach

822
if host_machine.cpu_family().startswith('x86')
823
  pre_args += '-DUSE_SSE41'
824 825 826 827 828 829 830 831 832 833 834 835
  with_sse41 = true
  sse41_args = ['-msse4.1']

  # GCC on x86 (not x86_64) with -msse* assumes a 16 byte aligned stack, but
  # that's not guaranteed
  if host_machine.cpu_family() == 'x86'
    sse41_args += '-mstackrealign'
  endif
else
  with_sse41 = false
  sse41_args = []
endif
836 837

# Check for GCC style atomics
838
dep_atomic = null_dep
839

840 841 842
if cc.compiles('int main() { int n; return __atomic_load_n(&n, __ATOMIC_ACQUIRE); }',
               name : 'GCC atomic builtins')
  pre_args += '-DUSE_GCC_ATOMIC_BUILTINS'
843 844 845 846 847 848 849 850 851

  # Not all atomic calls can be turned into lock-free instructions, in which
  # GCC will make calls into the libatomic library. Check whether we need to
  # link with -latomic.
  #
  # This can happen for 64-bit atomic operations on 32-bit architectures such
  # as ARM.
  if not cc.links('''#include <stdint.h>
                     int main() {
852 853 854 855
                       struct {
                         uint64_t *v;
                       } x;
                       return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE);
856 857 858 859
                     }''',
                  name : 'GCC atomic builtins required -latomic')
    dep_atomic = cc.find_library('atomic')
  endif
860 861 862 863 864 865 866 867 868 869 870 871 872 873
endif
if not cc.links('''#include <stdint.h>
                   uint64_t v;
                   int main() {
                     return __sync_add_and_fetch(&v, (uint64_t)1);
                   }''',
                name : 'GCC 64bit atomics')
  pre_args += '-DMISSING_64_BIT_ATOMICS'
endif

# TODO: endian
# TODO: powr8
# TODO: shared/static? Is this even worth doing?

874 875 876 877 878 879 880 881 882 883
# Building x86 assembly code requires running x86 binaries. It is possible for
# x86_64 OSes to run x86 binaries, so don't disable asm in those cases
# TODO: it should be possible to use an exe_wrapper to run the binary during
# the build. 
if meson.is_cross_build() 
  if not (build_machine.cpu_family() == 'x86_64' and host_machine.cpu_family() == 'x86'
          and build_machine.system() == host_machine.system())
    message('Cross compiling to x86 from non-x86, disabling asm')
    with_asm = false
  endif
Dylan Baker's avatar
Dylan Baker committed
884 885 886 887 888 889
endif

with_asm_arch = ''
if with_asm
  # TODO: SPARC and PPC
  if host_machine.cpu_family() == 'x86'
Greg V's avatar
Greg V committed
890
    if system_has_kms_drm
Dylan Baker's avatar
Dylan Baker committed
891 892 893 894 895
      with_asm_arch = 'x86'
      pre_args += ['-DUSE_X86_ASM', '-DUSE_MMX_ASM', '-DUSE_3DNOW_ASM',
                   '-DUSE_SSE_ASM']
    endif
  elif host_machine.cpu_family() == 'x86_64'
Greg V's avatar
Greg V committed
896
    if system_has_kms_drm
Dylan Baker's avatar
Dylan Baker committed
897 898 899 900
      with_asm_arch = 'x86_64'
      pre_args += ['-DUSE_X86_64_ASM']
    endif
  elif host_machine.cpu_family() == 'arm'
Greg V's avatar
Greg V committed
901
    if system_has_kms_drm
Dylan Baker's avatar
Dylan Baker committed
902 903 904 905
      with_asm_arch = 'arm'
      pre_args += ['-DUSE_ARM_ASM']
    endif
  elif host_machine.cpu_family() == 'aarch64'
Greg V's avatar
Greg V committed
906
    if system_has_kms_drm
Dylan Baker's avatar
Dylan Baker committed
907 908 909 910 911
      with_asm_arch = 'aarch64'
      pre_args += ['-DUSE_AARCH64_ASM']
    endif
  endif
endif
912 913 914 915 916 917 918 919

# Check for standard headers and functions
if cc.has_header_symbol('sys/sysmacros.h', 'major')
  pre_args += '-DMAJOR_IN_SYSMACROS'
elif cc.has_header_symbol('sys/mkdev.h', 'major')
  pre_args += '-DMAJOR_IN_MKDEV'
endif

920
foreach h : ['xlocale.h', 'sys/sysctl.h', 'linux/futex.h', 'endian.h']
921
  if cc.compiles('#include <@0@>'.format(h), name : '@0@'.format(h))
922 923 924 925
    pre_args += '-DHAVE_@0@'.format(h.to_upper().underscorify())
  endif
endforeach

926
foreach f : ['strtof', 'mkostemp', 'posix_memalign', 'timespec_get', 'memfd_create']
927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944
  if cc.has_function(f)
    pre_args += '-DHAVE_@0@'.format(f.to_upper())
  endif
endforeach

# strtod locale support
if cc.links('''
    #define _GNU_SOURCE
    #include <stdlib.h>
    #include <locale.h>
    #ifdef HAVE_XLOCALE_H
    #include <xlocale.h>
    #endif
    int main() {
      locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
      const char *s = "1.0";
      char *end;
      double d = strtod_l(s, end, loc);
945
      float f = strtof_l(s, end, loc);
946 947 948 949 950 951 952 953 954 955
      freelocale(loc);
      return 0;
    }''',
    extra_args : pre_args,
    name : 'strtod has locale support')
  pre_args += '-DHAVE_STRTOD_L'
endif

# Check for some linker flags
ld_args_bsymbolic = []
956
if cc.links('int main() { return 0; }', args : '-Wl,-Bsymbolic', name : 'Bsymbolic')
957 958 959 960
  ld_args_bsymbolic += '-Wl,-Bsymbolic'
endif
ld_args_gc_sections = []
if cc.links('static char unused() { return 5; } int main() { return 0; }',
961
            args : '-Wl,--gc-sections', name : 'gc-sections')
962 963
  ld_args_gc_sections += '-Wl,--gc-sections'
endif
964 965 966 967 968 969 970 971 972 973 974 975 976 977
with_ld_version_script = false
if cc.links('int main() { return 0; }',
            args : '-Wl,--version-script=@0@'.format(
              join_paths(meson.source_root(), 'build-support/conftest.map')),
            name : 'version-script')
  with_ld_version_script = true
endif
with_ld_dynamic_list = false
if cc.links('int main() { return 0; }',
            args : '-Wl,--dynamic-list=@0@'.format(
              join_paths(meson.source_root(), 'build-support/conftest.dyn')),
            name : 'dynamic-list')
  with_ld_dynamic_list = true
endif
978 979 980 981
ld_args_build_id = []
if build_machine.system() != 'darwin'
   ld_args_build_id += '-Wl,--build-id=sha1'
endif
982 983 984

# check for dl support
if cc.has_function('dlopen')
985
  dep_dl = null_dep
986 987 988
else
  dep_dl = cc.find_library('dl')
endif
Dylan Baker's avatar
Dylan Baker committed
989 990 991
if cc.has_function('dladdr', dependencies : dep_dl)
  # This is really only required for megadrivers
  pre_args += '-DHAVE_DLADDR'
992 993 994 995
endif

if cc.has_function('dl_iterate_phdr')
  pre_args += '-DHAVE_DL_ITERATE_PHDR'
996 997 998 999
elif with_intel_vk
  error('Intel "Anvil" Vulkan driver requires the dl_iterate_phdr function')
elif with_dri_i965 and get_option('shader-cache')
  error('Intel i965 GL driver requires dl_iterate_phdr when built with shader caching.')
1000 1001 1002 1003
endif

# Determine whether or not the rt library is needed for time functions
if cc.has_function('clock_gettime')
1004
  dep_clock = null_dep
1005 1006 1007 1008 1009 1010
else
  dep_clock = cc.find_library('rt')
endif

# TODO: some of these may be conditional
dep_zlib = dependency('zlib', version : '>= 1.2.3')
1011
pre_args += '-DHAVE_ZLIB'
1012
dep_thread = dependency('threads')
1013
if dep_thread.found() and host_machine.system() != 'windows'
1014 1015
  pre_args += '-DHAVE_PTHREAD'
endif
Dylan Baker's avatar
Dylan Baker committed
1016
if with_amd_vk or with_gallium_radeonsi or with_gallium_r600 or with_gallium_opencl
Dylan Baker's avatar
Dylan Baker committed
1017 1018 1019 1020 1021
  dep_elf = dependency('libelf', required : false)
  if not dep_elf.found()
    dep_elf = cc.find_library('elf')
  endif
else
1022
  dep_elf = null_dep
1023
endif
1024 1025 1026 1027
dep_expat = dependency('expat')
# this only exists on linux so either this is linux and it will be found, or
# its not linux and and wont
dep_m = cc.find_library('m', required : false)
Dylan Baker's avatar
Dylan Baker committed
1028

1029 1030 1031 1032
# Check for libdrm. various drivers have different libdrm version requirements,
# but we always want to use the same version for all libdrm modules. That means
# even if driver foo requires 2.4.0 and driver bar requires 2.4.3, if foo and
# bar are both on use 2.4.3 for both of them
1033 1034 1035 1036 1037 1038
dep_libdrm_amdgpu = null_dep
dep_libdrm_radeon = null_dep
dep_libdrm_nouveau = null_dep
dep_libdrm_etnaviv = null_dep
dep_libdrm_freedreno = null_dep
dep_libdrm_intel = null_dep
1039 1040 1041 1042

_drm_amdgpu_ver = '2.4.91'
_drm_radeon_ver = '2.4.71'
_drm_nouveau_ver = '2.4.66'
1043
_drm_etnaviv_ver = '2.4.89'
1044
_drm_freedreno_ver = '2.4.92'
1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057
_drm_intel_ver = '2.4.75'
_drm_ver = '2.4.75'

_libdrm_checks = [
  ['intel', with_dri_i915 or with_gallium_i915],
  ['amdgpu', with_amd_vk or with_gallium_radeonsi],
  ['radeon', (with_gallium_radeonsi or with_dri_r100 or with_dri_r200 or
              with_gallium_r300 or with_gallium_r600)],
  ['nouveau', (with_gallium_nouveau or with_dri_nouveau)],
  ['etnaviv', with_gallium_etnaviv],
  ['freedreno', with_gallium_freedreno],
]

1058 1059 1060 1061 1062 1063
# VC4 only needs core libdrm support of this version, not a libdrm_vc4
# library.
if with_gallium_vc4
  _drm_ver = '2.4.89'
endif

1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077
# Loop over the enables versions and get the highest libdrm requirement for all
# active drivers.
foreach d : _libdrm_checks
  ver = get_variable('_drm_@0@_ver'.format(d[0]))
  if d[1] and ver.version_compare('>' + _drm_ver)
    _drm_ver = ver
  endif
endforeach

# Then get each libdrm module
foreach d : _libdrm_checks
  if d[1]
    set_variable(
      'dep_libdrm_' + d[0],